sip через pptp

Тема в разделе "Маршрутизация", создана пользователем n_s_p, 8 июн 2016.

  1. n_s_p

    n_s_p Новый участник

    Здравствуйте!

    Решил настроить sip-телефон ISP1 через интернет ISP2. Для этого, на роутере ISP1 поднят PPTP-сервер, к которому подключается роутер ISP2 (клиент). схема на картинке.
    2016-06-08_11-38-04.png

    В локальной сети ISP1 есть sip-сервис (10.25.0.50, 195.239.174.100). На роутере ISP2 прописаны маршруты, чтоб пакеты на эти адреса уходили в созданный PPTP.

    Роутеры видят друг друга по PPTP. локальные сети за роутерами видят друг друга. но SIP не регистрируется через роутер ISP2, хотя, если подключить к роутеру ISP1 регистрация проходит успешно.

    Подскажите, куда копать?

    Конфиг ISP1
    Код:
    
    /interface bridge
    add arp=proxy-arp name=bridge1 protocol-mode=none
    
    /interface pptp-server
    add comment=Beeline_sip name=pptp-in2 user=beeline_sip
    
    /ip neighbor discovery
    set ether1 discover=no
    set pptp-in2 comment=Beeline_sip
    
    /ip pool
    add name=dhcp ranges=192.168.20.3-192.168.20.254
    
    /ip dhcp-server
    add address-pool=dhcp disabled=no interface=bridge1 name=dhcp1
    
    /interface bridge port
    add bridge=bridge1 interface=ether2
    add bridge=bridge1 interface=ether3
    add bridge=bridge1 interface=ether4
    add bridge=bridge1 interface=ether5
    
    /interface pptp-server server
    set enabled=yes
    
    /ip address
    add address=192.168.20.1/24 interface=ether2 network=192.168.20.0
    
    /ip dhcp-client
    add dhcp-options=hostname,clientid disabled=no interface=ether1
    
    /ip dhcp-server network
    add address=192.168.20.0/24 gateway=192.168.20.1 netmask=24
    
    /ip firewall address-list
    add address=0.0.0.0/8 list=BOGON
    add address=10.0.0.0/8 list=BOGON
    add address=100.64.0.0/10 list=BOGON
    add address=127.0.0.0/8 list=BOGON
    add address=169.254.0.0/16 list=BOGON
    add address=172.16.0.0/12 list=BOGON
    add address=192.0.0.0/24 list=BOGON
    add address=192.0.2.0/24 list=BOGON
    add address=192.168.0.0/16 list=BOGON
    add address=198.18.0.0/15 list=BOGON
    add address=198.51.100.0/24 list=BOGON
    add address=203.0.113.0/24 list=BOGON
    add address=224.0.0.0/4 list=BOGON
    add address=240.0.0.0/4 list=BOGON
    
    /ip firewall filter
    add action=fasttrack-connection chain=forward connection-state=established,related
    add chain=forward connection-state=established,related
    add chain=input comment="Allow IGMP" protocol=igmp
    add chain=input comment="Allow UDP" protocol=udp
    add chain=forward comment="Allow UDP" protocol=udp
    add chain=input dst-port=1723 protocol=tcp
    add chain=input protocol=gre
    add action=drop chain=input in-interface=ether1 src-address-list=BOGON
    add chain=input connection-state=established
    add chain=input connection-state=related
    add chain=input protocol=icmp
    add action=drop chain=input in-interface=!bridge1
    
    /ip firewall mangle
    add action=change-mss chain=forward disabled=yes in-interface=ether1 new-mss=1420 protocol=tcp tcp-flags=syn tcp-mss=1421-65535
    add action=change-mss chain=forward disabled=yes new-mss=1420 out-interface=ether1 protocol=tcp tcp-flags=syn tcp-mss=1421-65535
    
    /ip firewall nat
    add action=masquerade chain=srcnat out-interface=ether1
    
    add action=masquerade chain=srcnat dst-address=192.168.20.0/24 src-address=\
        192.168.21.0/24
     
    add action=masquerade chain=srcnat disabled=yes dst-address=\
        192.168.21.0/24 src-address=192.168.20.0/24
     
    /ip firewall service-port
    set sip disabled=yes
    
    /ip route
    add distance=1 dst-address=192.168.3.0/24 gateway=pptp-in2
    
    /ip upnp
    set enabled=yes
    
    /ip upnp interfaces
    add interface=bridge1 type=internal
    add interface=ether1 type=external
    
    /ppp secret
    add local-address=192.168.21.1 name=beeline_sip password=XXX profile=default-encryption remote-address=192.168.21.9 service=pptp
    

    Конфиг ISP2
    Код:
    /interface ethernet
    set [ find default-name=ether1 ] name=ether1-gateway
    set [ find default-name=ether2 ] name=ether2-master-local
    set [ find default-name=ether3 ] master-port=ether2-master-local name=\
        ether3-slave-local
    set [ find default-name=ether4 ] master-port=ether2-master-local name=\
        ether4-slave-local
    set [ find default-name=ether5 ] master-port=ether2-master-local name=\
        ether5-slave-local
      
    /interface pptp-client
    add allow=mschap2 comment=Beeline_sip connect-to=XXX.sn.mynetname.net \
        disabled=no name=Beeline_sip password=XXXX user=XXXX
      
    /ip neighbor discovery
    set ether1-gateway discover=no
    set ether3-slave-local discover=no
    set ether4-slave-local discover=no
    set ether5-slave-local discover=no
    set Beeline_sip comment=Beeline_sip
    
    /ip pool
    add name=dhcp ranges=192.168.3.10-192.168.3.254
    
    /ip dhcp-server
    add address-pool=dhcp disabled=no interface=ether2-master-local name=default
    
    /ip address
    add address=192.168.3.1/24 comment="default configuration" interface=\
        ether2-master-local network=192.168.3.0
    
    /ip dhcp-client
    add comment="default configuration" dhcp-options=hostname,clientid disabled=no \
        interface=ether1-gateway
      
    /ip dhcp-server network
    add address=192.168.3.0/24 comment="default configuration" gateway=192.168.3.1
    
    /ip firewall address-list
    add address=0.0.0.0/8 list=BOGON
    add address=10.0.0.0/8 list=BOGON
    add address=100.64.0.0/10 list=BOGON
    add address=127.0.0.0/8 list=BOGON
    add address=169.254.0.0/16 list=BOGON
    add address=172.16.0.0/12 list=BOGON
    add address=192.0.0.0/24 list=BOGON
    add address=192.0.2.0/24 list=BOGON
    add address=192.168.0.0/16 list=BOGON
    add address=198.18.0.0/15 list=BOGON
    add address=198.51.100.0/24 list=BOGON
    add address=203.0.113.0/24 list=BOGON
    add address=224.0.0.0/4 list=BOGON
    add address=240.0.0.0/4 list=BOGON
    
    /ip firewall filter
    add action=fasttrack-connection chain=forward comment="default configuration" \
        connection-state=established,related
    add chain=input comment="default configuration" protocol=icmp
    add chain=input comment="default configuration" connection-state=established,related
    add chain=input connection-state=new \
        dst-port=1723 protocol=tcp
    add chain=forward comment="default configuration" connection-state=\
        established,related
    add action=drop chain=input comment="default configuration" in-interface=\
        ether1-gateway
    add action=drop chain=forward comment="default configuration" connection-state=\
        invalid
    add action=drop chain=forward comment="default configuration" connection-nat-state=\
        !dstnat connection-state=new in-interface=ether1-gateway
    add action=drop chain=input in-interface=ether1-gateway src-address-list=BOGON
    add action=drop chain=input connection-state=new disabled=yes in-interface=\
        !ether2-master-local
      
    /ip firewall nat
    add action=masquerade chain=srcnat comment="default configuration" out-interface=ether1-gateway
    add action=masquerade chain=srcnat out-interface=Beeline_sip
    
    /ip firewall service-port
    set sip disabled=yes
    
    /ip route
    add distance=1 dst-address=10.25.0.50/32 gateway=Beeline_sip
    add distance=1 dst-address=192.168.20.0/24 gateway=Beeline_sip
    add distance=1 dst-address=195.239.174.100/32 gateway=Beeline_sip
    
    
     
    Последнее редактирование: 8 июн 2016
  2. Илья Князев

    Илья Князев Администратор Команда форума

    Зачем вам при этом двойной NAT это раз
    Далее. А на АТС NAT настроен? Если настроен, попробуйте выключить sip в /service ports в файрволле.
     
  3. n_s_p

    n_s_p Новый участник

    в конфиге 1, 2 sip ports выключен
    Код:
    /ip firewall service-port set sip disabled=yes
    
    в конфиге 1 - 1 нат для pptp. на АТС (gigaset a510ip) настройки не изменял. при подключении ip-телефона к роутеру ISP1 сервис работает.
     
  4. Илья Князев

    Илья Князев Администратор Команда форума

    У вас в конфете 2 включен НАТ и выключен СИП.
     
  5. n_s_p

    n_s_p Новый участник

    да, первая строка нат для 3.0/24 вторая строчка для 21.0/24. не очень понимаю вопрос про двойной нат.
     
  6. Илья Князев

    Илья Князев Администратор Команда форума

    Вы делаете SRC-NAT на ISP2 и отключаете NAT-Helper на SIP. При этом легко может не работать.
     
  7. n_s_p

    n_s_p Новый участник

    вобщем sip ports не включал. добавил строку в конфиг роутера ISP2
    Код:
    /ip firewall filter add chain=forward comment="Allow UDP" protocol=udp
    
    и ребутнул.

    регистрация прошла успешно. звонки ходят туда-сюда. осталось разобраться со слышимостью, так как не слышно на двух концах разговора.
     
  8. Илья Князев

    Илья Князев Администратор Команда форума

    А вот за это и отвечает Helper. Поиграйте там еще галочкой Direct Media
     
  9. n_s_p

    n_s_p Новый участник

    sip ALG (helper) может и помогает, но не у Билайна! у них регистрация проходит по 10.25.0.50:5060, а разговор идет уже по 10.25.0.36.
    [​IMG]
    добавил на роутере ISP2 правило маршрутизации:
    Код:
    /ip route add distance=1 dst-address=10.25.0.36/32 gateway=Beeline_sip
    
    и все взлетело! и звонки идут и слышно всё хорошо!

    Илья, спасибо за помощь!
     
    Последнее редактирование: 10 июн 2016
  10. Илья Князев

    Илья Князев Администратор Команда форума

    ОК. Отлично.